import org.codehaus.groovy.grails.plugins.web.taglib.FormTagLib

class JTFormTagLib extends FormTagLib {
	static namespace = "jttext"

	static String javascript = """
<script>
 	function checkLength(elementId, maxLength) {
 		var field = \$(elementId);
 		var value = field.value;
 		if(value.length>maxLength) {
 			field.value=value.substring(0,maxLength);
 		}
 		if(\$(elementId+'Counter')) 
 			\$(elementId+'Counter').innerHTML=maxLength-field.value.length+' characters left';
 	}
        function checkTab(event, field) {
            if(event.keyCode==9) {field.value=insert(field.value, field.selectionStart,String.fromCharCode(9));setTimeout("field.focus()",0);return false;}
        }
        function insert(str, pos, value) {
            return str.substring(0,pos)+value+str.substring(pos+1);
        }

</script>
"""
        /* deprecated: bad name - use script instead */
	def changeScript = { attrs ->
		out << javascript
	}

	def script = { attrs ->
		out << javascript
	}
	
        /**
         * Creates a TextArea HTML element, where the maximum number of characters is 
         * limited by the constraints on the domain object, and tabs can be allowed if
         * desired.
         * 
         * Sample use:
         *       <g:javascript library=”prototype”/>
         *       <jttext:script />
         *       ...
         *       <jttext:textArea object="${new Book()}" name="content" allowTabs="true"/>
         *       <jttext:statusDiv for="content" />
         *
         * The number of remaining characters available are displayed in the status div.
         * If allowTabs is set to true, tabs can be entered in the text area.
         */
	def textArea = {attrs ->
            resolveAttributes(attrs)
	    attrs.id = attrs.id ? attrs.id : attrs.name
	    
            // Pull out values to use as content not attrib
	    def object = attrs.remove('object')
            def maxlength = object.constraints."${attrs.name}".getMaxSize()
            def value = fieldValue(bean:object,field:attrs.name)
	    
	    def escapeHtml = true
	    if (attrs.escapeHtml) escapeHtml = Boolean.valueOf(attrs.remove('escapeHtml'))
            def allowTabs = Boolean.valueOf(attrs.remove('allowTabs'))

            def onKeyDown = ""
            def onKeyUp = ""

            if(maxlength) {
                onKeyDown = "checkLength('${attrs.id}',${maxlength});"
                onKeyUp = "checkLength('${attrs.id}',${maxlength});"
            }
            if(allowTabs) {
                onKeyDown += "checkTab(event, this);"
            }
            attrs.put('onkeydown',onKeyDown)
            attrs.put('onkeyup',onKeyUp)
	    out << "<textarea " 
	    outputAttributes(attrs) 
	    out << ">" << (escapeHtml ? value.encodeAsHTML() : value) << "</textarea>" 
	}

	def statusDiv = { attrs ->
		out << "<div id=\"${attrs.for}Counter\">&nbsp;</div>"	
	}

    /** Creates a text input type using maxlength from the objects constraints.
     *   Sample use:
     *       <g:javascript library=”prototype”/>
     *       <jttext:script />
     *        ...
     *       <jttext:textField object="${book}" name="title"/>
     *
     *   Generates:
     *       <input type="text" name="title" maxlength=”20″ value=”my new book” id=”title” />
     *
     *   When Book.groovy looks like:
     *    class Book {
     *      String title="my new book"
     *
     *      static def constraints = {
     *         title(maxSize:20)
     *      }
     *    }
     */  
    def textField = {attrs ->
        attrs.type = "text"
        attrs.tagName = "textField"

        def object = attrs.remove('object')
        def maxlength = object.constraints."${attrs.name}".getMaxSize()
        if(maxlength) {
            attrs.put('maxlength', maxlength)
        }
        attrs.put('value', fieldValue(bean:object,field:attrs.name))

        def result = field(attrs)
        if (result) {
            out << result
        }
    }
}